PIC Microcontoller Delay Method

Delay X cycles (20-271) inclusive

From Andrew Warren

    ; This routine delays X cycles.  Enter with X (in the range
    ; [20-271]) in the W register.
    ;
    ; Note that the delay is inclusive of the "MOVLW X", "CALL
    ; DELAY", and "RETURN" overhead, so a sequence like:
    ;
    ;     MOVLW   100
    ;     CALL    DELAY
    ;     MOVLW   200
    ;     CALL    DELAY
    ;
    ; will delay EXACTLY 300 cycles.

    DELAY:

        MOVWF   COUNTER

        BTFSC   COUNTER, 0
        GOTO    $+1

        BTFSS   COUNTER, 1
        GOTO    SKIP
        NOP
        GOTO    $+1

    SKIP:

        RRF     COUNTER
        RRF     COUNTER

        MOVLW   4
        SUBWF   COUNTER

        BCF     COUNTER,6
        BCF     COUNTER,7

    LOOP:

        NOP
        DECFSZ  COUNTER
        GOTO    LOOP

        RETURN

PICList 2008 contributors: o List host: MIT, Site host massmind.org, Top posters @20080720 Apptech, Jinx, Xiaofan Chen, olin piclist, Alan B. Pearce, David VanHorn, William \Chops\ Westfield, Tamas Rudnai, Cedric Chang, bean, * Page Editors: James Newton, David Cary, and YOU! * Roman Black of Black Robotics donates from sales of Linistep stepper controller kits. * Ashley Roll of Digital Nemesis donates from sales of RCL-1 RS232 to TTL converters. * Monthly Subscribers: Shultz Electronics, Timothy Weber, on-going support is MOST appreciated! * Contributors: Richard Seriani, Sr.

  .