> Yes.
>  Input: 2 registers

>   Temp: 1 register

> Output: 1 register
> -------------------
>  total: 4 registers

> Required at compile time: 1 subroutine to do something nice with the Output
> value and it can then munch it. For example, you can shift the output
> register out a port pin, leaving behind a zero.

> The only thing that the main routine has to do is call the subroutine for
> each digit of output with a valid number between 0 and 9 (or '0' and '9') in
> the output register.

> Possible improvements for extra credit (not in my code):
> It would be nice if it had an option to output a "." after some number of
> digits passed as a third input.
> It would be nice to optionally skip leading digits that are zero.

> Code that cannot be written for the PIC:
> A general purpose routine that is given a pointer (FSR) to a register
> holding the radix and followed by a count of the number of following bytes
> that contain the binary number to be converted. Output each digit as it is
> developed.

> ---
> James Newton KILLspamjamesnewtonKILLspamgeocities.com 1-619-652-0593
> http://techref.massmind.org NEW! FINALLY A REAL NAME!
> Members can add private/public comments/pages ($0 TANSTAAFL web hosting)


> -----Original Message-----
> From: pic microcontroller discussion list
> [RemoveMEPICLISTTakeThisOuTMITVMA.MIT.EDU]On Behalf Of Rich Leggitt
> Sent: Thursday, March 09, 2000 14:39
> To: spamBeGonePICLISTspamBeGoneMITVMA.MIT.EDU
> Subject: Re: How to write code that no one will laugh at [OT]


>> Ok, I have a (probably little and fairly lame) code challenge! [ed: which
>> will probably be ignored 'cause its in Parallax mnemonics and its lame]
> Do we get to destroy the original 16 bit number?

> That certainly works and is probably the shortest code. It has the added
> advantage of not really needing a temp register (your temp is the output as
> well). Its the same idea that Scott Edwards used in his Serout routine but
> with a over, under, over, under optimization. Very Nice. See:
> www.dontronics.com/convert2.html#serout2
> But the 1 loop per digit is just very slow.... uh.... no I just did some
> counting and I have 215 instructions worst case for this routine! 60900 is
> the worst case right? Wow! I have to test this, but if it really works (and
> I don't see why it shouldn't), this is better than Payson's. Its smaller and
> is probably faster on the average, and requires no temp register.
>
> Kicks my routine all to heck! Thanks! My boss will think I'm a genius...
> <GRIN>
>
> ---
> James Newton jamesnewtonEraseME.....geocities.com 1-619-652-0593
> http://techref.massmind.org NEW! FINALLY A REAL NAME!
> Members can add private/public comments/pages ($0 TANSTAAFL web hosting)
>
>

>
> You could maybe use some idle control like SSPCON or INDF for known_zero.
> But I may start canonically defining a ZERO file register for just this
> kind of thing, it's completely free until out of RAM at which point subtle
> optimization isn't the issue :).
>
> >    skp            ;is this a valid macro? I'd write goto $+2 ...
> Um. Well it SHOULD be. :)
>
> > sub100
> >    incf  temp,f
> >    subwf LO,f
> >    skpc
> >     goto sub100
> >
> >    decf  HI,f
> >    btfss HI,7    ;Check msb instead of carry for underflow.
> >     goto sub100
>
> Good point. What about:
>
>         clrf temp,f
>         movlw 100
>         incf HI,f       ; 1<=HI<=4
>         goto $+2        ;
> sub100  incf temp,f
>         subwf LO,f
>         skpnc
>         decfsz HI,f
>         goto sub100

> Nice. Thanks Scott.

> The 8 bit to BCD routine is 28 instructions by my count. I have it at
> techref.massmind.org/microchip/math/radix/b2bhp-8b3d
> and I think it would require another temp... well... no I guess you could
> reuse HI. It would also need extra (trivial) code to separate tens and ones.

> Summary:

> As I don't know the MChip syntax for conditional compilation, I have:

> ; by Rich Leggitt with tweaks by Scott Dattalo
> ; given 16 bit data in HI and LO, extract decimal digits
> ; requires one Output register called temp, HI and LO are destroyed.
> ; 42? instructions less than 217 (or 199 with known_zero) instructions
> executed
>         clrf temp
>         skp
> sub10k  incf temp,f
>         movlw 10000 & 255
>         subwf LO,f

> ;Scott Dattalo says:
> ;If you have a ram location that's known to be zero, then
> ;the following [the IF] can be replaced with [the ELSE]
> IFNDEF known_zero
>         movlw 10000 >> 8
>         skpc
>         addlw 1         ; this sucks
>         subwf HI,f
> ELSE
>         rlf   known_zero,w
>         addlw 10000 >> 8
>         subwf HI,f
> ENDIF
>         bc sub10k               ;48/39 inst in loop for 60900 (worst)
>         output(temp);

>         movlw 10
>         movwf temp
> add1K   decf temp,f
>         movlw 1000 & 255
>         addwf LO,f

> ;Scott Dattalo says:
> ;If you have a ram location that's known to be zero, then
> ;the following [the IF] can be replaced with [the ELSE]
> IFNDEF known_zero
>         movlw 1000 >> 8
>         skpnc
>         addlw 1
>         addwf HI,f
> ELSE
>         rlf   known_zero,w
>         addlw 1000 >> 8
>         addwf HI,f
> ENDIF
>         bnc add1k               ;72/63 inst in loop for 60900
>         output(temp);

> ;Scott takes over here
>         clrf  temp
>         movlw 100
>         skp            ;is this a valid macro? I'd write goto $+2 ...
> sub100
>         incf  temp,f
>         subwf LO,f
>         skpc
>         goto sub100

>         decf  HI,f
>         btfss HI,7      ;Check msb instead of carry for underflow.
>         goto sub100     ;4 inst per loop to 200 then 7 per loop to 900.
>                         ;Total 57(?) in loop for worst case

> ;at this point, HI = 0xff, and  0 <= LO <= 99

>         output(temp)

>         movlw 10
>         movwf temp
> add10   decf temp,f
>         addwf LO,f
>         bnc add10               ;27 inst in loop for worst case.
>         output(temp);
>         output(LO);
>         return


> ---
> James Newton RemoveMEjamesnewtonTakeThisOuTspamgeocities.com 1-619-652-0593
> http://techref.massmind.org NEW! FINALLY A REAL NAME!
> Members can add private/public comments/pages ($0 TANSTAAFL web hosting)


> -----Original Message-----
> From: Scott Dattalo [EraseMEscottspamspamBeGonedattalo.com]
> Sent: Friday, March 10, 2000 10:27
> To: James Newton
> Cc: RemoveMEPICLISTKILLspamMITVMA.MIT.EDU
> Subject: Re: How to write code that no one will laugh at [OT]
> Importance: Low



> I added a few things that'll speed it up...

> ; similarly:
>
> >         movlw 1000 >> 8
> >         skpnc
> >         addlw 1
> >         addwf HI,f
>
>   rlf   known_zero,w
>   addlw 1000 >> 8
>   addwf HI,f