Searching \ for 'Ham Radio related witchcraft' in subject line. ()
Make payments with PayPal - it's fast, free and secure! Help us get a faster server
FAQ page: www.piclist.com/techref/index.htm?key=ham+radio+related
Search entire site for: 'Ham Radio related witchcraft'.

Truncated match.
PICList Thread
'Ham Radio related witchcraft'
1996\05\29@223318 by Mark K Sullivan

flavicon
face
Paul Smith wrote:
>My interest with PIC is mainly for the control of amateur radio related
>equipment such as repeaters and beacon controllers.

...beacon CONTROLLER!  In the following, the PIC is the whole beacon.  Just add
a crystal, power (I use three 1.5V alkalines) and connect an antenna to OSC OUT.

Also note this adjusts the prescaler of the watchdog as discussed earlier.

- Mark Sullivan  (aka spam_OUTKB0VVQTakeThisOuTspamniobrara.com) -

       ;
       ; PIC16C54 based CW beacon
       ; Mark K Sullivan      01Apr96
       ;    PIC16C54 Version
       ;
;
; 01Apr96 - MKS
;
       ;
;
; Connect PIC oscillator to 28 or 29.??? MHz crystal in the 10 meter band.
; Program fuses to enable WDT and select HS oscillator mode.
; Alter timing in DELAY routine for a substantially different crystal.
;
; This program identifies a CW beacon by switching the PIC's
; own oscillator on and off.  Carrier-on delays are generated
; with a timing loop.  Carrier-off periods are timed by the WDT
; with the CPU in sleep state.  The PIC oscillator output should
; be fed to the antenna either directly or via an amplifier stage.
; If an external amplifier is added, pin PB0 or PB1 can be used to
; enable it.  PB0 high or PB1 low should turn on the amplifier.
;
; The Morse keying rate must be a power-of-two multiple
; of the 18 mS nominal WDT period.  I have chosen 72mS
; for the smallest element.  This yields about 17 WPM keying.
; The relative duration of Morse code elements is as follows:
;
; dit = 1, dah = 3
; inter-element delay = 1
; inter-character delay = 4 (ARRL says 3 but that's not 2^n)
;
; Remember that WDT timing does not depend on the crystal.  Changing
; the crystal without adjusting program timing will alter the
; relative timing of carrier-on and carrier-off elements, not
; simply scale the timing.
;
       ;
       PROCESSOR       PIC16C54
       RADIX   DEC
       ;
       #define W 0
       cblock  0       ;special function registers
       indf
       rtcc
       pc
       status
       fsr
       porta
       portb
       portc   ;16C55, 57 only
       endc
       ;
       cblock  8       ;this program's variables
       Point           ;index into message table
       Timer1          ;counters for time dealy routine
       Timer2
       Timer3
       Timer4          ;used to time the 1 minute delay
       endc
       ;
       org     0
       ;
;
; Here is the table of symbols to send. Don't exceed 255 entries
; in the table, including the end marker.
;
#define space   1       ;key inter-character space
#define silence 2       ;key 1 sec of silence
#define dit     4       ;key Morse .
#define dah     5       ;key Morse -
#define carrier 6       ;key 1 sec of carrier
#define minute  7       ;key 1 minute of carrier
;
table   addwf   pc
;
; This example ID table sends 5 seconds of carrier,
; a one second silence,
; the call sign KB0VVQ,
; another one second silence,
; and then repeats.
;
       retlw   carrier ;five seconds of carrier
       retlw   carrier
       retlw   carrier
       retlw   carrier
       retlw   carrier
       retlw   silence ;one second silence
       retlw   dah     ;K
       retlw   dit
       retlw   dah
       retlw   space
       retlw   dah     ;B
       retlw   dit
       retlw   dit
       retlw   dit
       retlw   space
       retlw   dah     ;0
       retlw   dah
       retlw   dah
       retlw   dah
       retlw   dah
       retlw   space
       retlw   dit     ;V
       retlw   dit
       retlw   dit
       retlw   dah
       retlw   space
       retlw   dit     ;V
       retlw   dit
       retlw   dit
       retlw   dah
       retlw   space
       retlw   dah     ;Q
       retlw   dah
       retlw   dit
       retlw   dah
       retlw   silence ;one second silence
       ;
       retlw   0       ;end of table, start over
       ;
;
; Vector to RESET at power-up or when WDT expires
;
RESET   movlw   00h
       movwf   porta   ;turn off outputs
       movwf   portb
       tris    porta   ;all pins are outputs
       tris    portb
       btfss   status,4 ;test TO bit, skip if cold start
       goto    NEXT    ;this reset was a WDT timeout
       ;
LOOP    clrf    Point   ;start at top of table
symbol  bsf     portb,0 ;turn on final amp
       bcf     portb,1
       movf    Point,W
       call    table   ;look up table entry
       addwf   pc
       goto    LOOP    ;0 entry is table end
       goto    dospc   ;inter-character space
       goto    dosil   ;1 sec of silence
       goto    NEXT    ;code 3 - unimplemented
       goto    dodit
       goto    dodah
       goto    dosec   ;1 sec of carrier
       goto    domin   ;1 minute of carrier
NEXT    incf    Point
       goto    symbol
       ;
dodit   movlw   72
       goto    didah
       ;
dodah   movlw   3*72
didah   call    DELAY
       movf    Point,W
       call    table   ;look up table entry
       andlw   04h     ;test silence bit
       btfss   _z      ;skip if next element is not silent
       goto    NEXT    ;don't key inter-element space
       movlw   0ah
       option          ;set WDT timeout to 72 mS
       bcf     portb,0 ;turn off final
       bsf     portb,1
       sleep
       ;
dospc   movlw   0ch
       option          ;set WDT timeout to 4*72 mS
       bcf     portb,0 ;turn off final
       bsf     portb,1
       sleep
       ;
dosil   movlw   0eh
       option          ;set WDT timeout to 1152 mS
       bcf     portb,0 ;turn off final
       bsf     portb,1
       sleep
       ;
dosec   movlw   250     ;simply delay for 1 second
       call    DELAY
       movlw   250
       call    DELAY
       movlw   250
       call    DELAY
       movlw   250
       call    DELAY
       goto    NEXT
       ;
domin   movlw   60*4    ;a full minute of carrier
       movwf   Timer4
min1    movlw   250
       call    DELAY
       decfsz  Timer4
       goto    min1
       goto    NEXT
       ;
;
; Call DELAY with W the duration of desired delay in milliseconds.
; Calibrated approximately for 29.??? MHz crystal.
;
DELAY   movwf   Timer1
d0      movlw   7       ;change this constant for different crystals
       movwf   Timer2
d1      clrwdt
       decfsz  Timer3
       goto    d1
       decfsz  Timer2
       goto    d1
       decfsz  Timer1
       goto    d0
       retlw   0
       ;
       org     1ffh    ;PIC16C54 reset vector
       ;
       goto    RESET
       ;
       end


'Ham Radio related witchcraft'
1996\06\01@081538 by Richard Rogers
flavicon
face
msullivan@VAX.NIOBRARA.COM> writes:

>...beacon CONTROLLER!  In the following, the PIC is the whole beacon.  Just add
>a crystal, power (I use three 1.5V alkalines) and connect an antenna to OSC
OUT.

Wonderful idea, Mark.

>; The relative duration of Morse code elements is as follows:
>; dit = 1, dah = 3
>; inter-element delay = 1
>; inter-character delay = 4 (ARRL says 3 but that's not 2^n)

If you always have an inter-element delay after each dit and dah, you can make
the inter-character delay = 2, and then the Morse timing will be correct.

I am converting your program to run on a 16C84, but haven't got it working
(yet).   WDT is new to me.   73

.-._/\
/      \
\_.--._/
     v <--- Richard Rogers, .....VK7ROKILLspamspam@spam@hba.trumpet.com.au

1996\06\01@211405 by Wynn Rostek

flavicon
face
At 11:55 AM 6/1/96 GMT+1000, you wrote:
>msullivanspamKILLspamVAX.NIOBRARA.COM> writes:
>
>>...beacon CONTROLLER!  In the following, the PIC is the whole beacon.
Just add
{Quote hidden}

I've got a bunny controller using a 16C84.  One minute on, one minute off with
a CW ID at the beginning and the end of the transmission.  The tone is
generated by toggling one of the PIC's output pins.  Another output pin
is used to key the HT.  I can send code if anyone is really interested.

Ain't PIC's great?  Went to the PIC seminar yesterday.  Bought a PicStart Plus,
but haven't used it yet.  Anyone know about the 8 pin PICs Microchip has
come out with?  I hear that they are around 50 cents each (US) in quantity.
Beacon/Bunny controllers only need 2 or 3 output pins....

Wynn Rostek
Wynn Rostek
EraseMEwarspam_OUTspamTakeThisOuTpalmnet.net
wynnspamspam_OUTpitcairn.ksc.nasa.gov
@spam@wynn.rostekKILLspamspamksc.nasa.gov

Other Email addresses available if you really need 'em...

1996\06\01@211818 by Wynn Rostek

flavicon
face
At 11:55 AM 6/1/96 GMT+1000, you wrote:
>KILLspammsullivanKILLspamspamVAX.NIOBRARA.COM> writes:
>
>>...beacon CONTROLLER!  In the following, the PIC is the whole beacon.
Just add
>>a crystal, power (I use three 1.5V alkalines) and connect an antenna to OSC
> OUT.
>
>Wonderful idea, Mark.


Oh, I've also got 16C84 code for a sniffer.  It has outputs to switch between
two antennas at 400 Hz, and one input is used for audio from the HT.  Two
outputs drive LEDs for phase indication.  (Turn left/right right around
the null.)  I can send that also if anyone wants it.  (Not as much of a pure
PIC project as it does have an 8th order active filter that sits between
the audio input and the PIC input.

Wynn Rostek
Wynn Rostek
RemoveMEwarTakeThisOuTspampalmnet.net
spamBeGonewynnspamBeGonespampitcairn.ksc.nasa.gov
TakeThisOuTwynn.rostekEraseMEspamspam_OUTksc.nasa.gov

Other Email addresses available if you really need 'em...

1996\06\01@225137 by Henry Carl Ott

picon face
At 08:12 PM 6/1/96 -0400, you wrote:
-snip snip-----------------------------------
>I've got a bunny controller using a 16C84.  One minute on, one minute off with
>a CW ID at the beginning and the end of the transmission.  The tone is
>generated by toggling one of the PIC's output pins.  Another output pin
>is used to key the HT.  I can send code if anyone is really interested.
>
>Ain't PIC's great?  Went to the PIC seminar yesterday.  Bought a PicStart Plus,
>but haven't used it yet.  Anyone know about the 8 pin PICs Microchip has
>come out with?  I hear that they are around 50 cents each (US) in quantity.
>Beacon/Bunny controllers only need 2 or 3 output pins....
>
>Wynn Rostek
>Wynn Rostek
>RemoveMEwarspamTakeThisOuTpalmnet.net
>wynnEraseMEspam.....pitcairn.ksc.nasa.gov
>EraseMEwynn.rostekspamksc.nasa.gov

Yes PIC's are great! If I'm not carefull I'll find myself using them when a
LM555 would be more appropriate.
Speaking of 8 pin devices, I was also just at a seminar and I don't
remember any references to 8 pin PIC's. Unless you are referring to the
KEELOQ encoder chip?


carl

----------------------------------------------------------------
Henry Carl Ott   N2RVQ   | talk/chat  carlott@204.74.7.186
RemoveMEcarlottEraseMEspamEraseMEinterport.net    | http://www.interport.net/~carlott/
----------------------------------------------------------------
"A day job...in an office? My worst nightmare!"-Ticknophobia

1996\06\01@231052 by John Payson

flavicon
face
>  Speaking of 8 pin devices, I was also just at a seminar and I don't
> remember any references to 8 pin PIC's. Unless you are referring to the
> KEELOQ encoder chip?

Per Microchip's web site, there ARE going to be 8-pin devices.  By the
sound of it, they're equivalent to the 16C54 except:

[1] No external clock generator (internal 4MHz)

[2] Code=512, Data=25, like the 54

[3] Watchdog unknown

[4] No external reset (or RTCC?) input

[5] Only 6 I/O pins [I don't know whether portB only or some portA some portB

[6] Price under $1.

More... (looser matching)
- Last day of these posts
- In 1996 , 1997 only
- Today
- New search...