>
> Roman:
> <snip>
> Sam, the skpc, skpnc etc are official Microchip mnemonics that
> simply equate to the ridiculous "btfsc STATUS,C" stuff that
> mightmares are made of. You actually prefer that??
> <snip>
>
> I agree that the Microchip mnemonics are the "stuff that nightmares are made
> of." Do I prefer them? No.
>
> <snip>
> The incw and decw are my custom ones... I find it hard
> to believe that you would have difficulty interpreting my
> "incw" instruction... :o)
> <snip>
>
> It isn't so much a case of interpreting your custom mnemonics, it's a case
> of trying to learn everyone's custom mnemonics. If everyone created a
> different custom instruction for a basic Microchip mnemonic, I'd go nuts
> trying to remember all the variations.
>
> It's somewhat akin to what happened with Unix. By making the source of their
> utility programs available for modification, everyone and their brother
> created variations on a theme. So, anytime you went to a different Unix
> shop, you would encounter similar utilities under a wide range of names.
> (Any Unix folks who take umbrage to this, please don't respond, I've been
> down that road too many times)
>
> Since you correctly pointed out that "skpc, skpnc etc are official Microchip
> mnemonics", I can't argue that those would be acceptable in a PIC assembly
> language program. However, as I discovered, not all compilers accept them as
> such. For example, Hi-Tech C does not recognize the special instruction
> mnemonics, thus I must always use the basic Microchip instruction set.
>
>         Sam....

>
> > > SKIP_WLE  ;skip if W less than or equal from last SUBLW or SUBWF
> > > SKIP_WGT  ;skip if W greater than ...
> >
> > I really like those skip_wle and skip_wgt mnemonics! Thanks,
> > will make good use of those in the future! Does anyone else
> > have any other good ones?
>
> Since you plan on using them, I have included the source code below to save
> you the trouble of re-creating them.
>
> ;
> ;********************
> ;
> ;   Macro SKIP_WLE
> ;
> ;   Skip the next instruction if W was less than or equal to the value
> ;   it was subtracted from.  This assumes that the carry flag has been
> ;   preserved from the last SUBWF or SUBLW instruction.
> ;
> skip_wle macro
>   if fam_17
>          btfss   alusta, c
>          exitm
>     endif
>
>          btfss   status, c   ;skip if no borrow occurred
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_WGT
> ;
> ;   Skip the next instruction if W was greater than the value
> ;   it was subtracted from.  This assumes that the carry flag has been
> ;   preserved from the last SUBWF or SUBLW instruction.
> ;
> skip_wgt macro
>   if fam_17
>          btfsc   alusta, c
>          exitm
>     endif
>
>          btfsc   status, c   ;skip if a borrow occurred
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_Z
> ;
> ;   Skip the next instruction if the zero flag is set.
> ;
> skip_z   macro
>   if fam_17
>          btfss   alusta, z
>          exitm
>     endif
>
>          btfss   status, z
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_NZ
> ;
> ;   Skip the next instruction if the zero flag is not set.
> ;
> skip_nz  macro
>   if fam_17
>          btfsc   alusta, z
>          exitm
>     endif
>
>          btfsc   status, z
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_CARR
> ;
> ;   Skip the next instruction if a carry occurred.
> ;
> skip_carr macro
>   if fam_17
>          btfss   alusta, c
>          exitm
>     endif
>
>          btfss   status, c
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_NCARR
> ;
> ;   Skip the next instruction if no carry occurred.
> ;
> skip_ncarr macro
>   if fam_17
>          btfsc   alusta, c
>          exitm
>     endif
>
>          btfsc   status, c
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_BORR
> ;
> ;   Skip the next instruction if a borrow occurred.
> ;
> skip_borr macro
>   if fam_17
>          btfsc   alusta, c
>          exitm
>     endif
>
>          btfsc   status, c
>          endm
> ;
> ;********************
> ;
> ;   Macro SKIP_NBORR
> ;
> ;   Skip the next instruction if no borrow occurred.
> ;
> skip_nborr macro
>   if fam_17
>          btfss   alusta, c
>          exitm
>     endif
>
>          btfss   status, c
>          endm
> ;
> ;********************
> ;
> ;   Macro INTR_OFF
> ;
> ;   Globally disable interrupts without changing which interrupts are
> ;   individually disabled.  This macro together with INTR_ON can be used
> ;   around small sections of code that need to run with interrupts off.
> ;
> intr_off macro
>   if fam_16
>          bcf     intcon, gie
>     endif
>   if fam_17
>          bsf     cpusta, glintd
>     endif
>          endm
> ;
> ;********************
> ;
> ;   Macro INTR_ON
> ;
> ;   Globally enable interrupts without changing which interrupts are
> ;   individually enabled.  This macro together with INTR_OFF can be used
> ;   around small sections of code that need to run with interrupts off.
> ;
> intr_on  macro
>   if fam_16
>          bsf     intcon, gie
>     endif
>   if fam_17
>          bcf     cpusta, glintd
>     endif
>          endm
>
> *****************************************************************
> Olin Lathrop, embedded systems consultant in Devens Massachusetts
> (978) 772-3129, .....olinKILLspam@spam@cognivis.com, http://www.cognivis.com
>
> --
> http://www.piclist.com hint: The PICList is archived three different
> ways.  See http://www.piclist.com/#archives for details.

> WAS:
> > intr_off macro
> >   if fam_16
> >          bcf     intcon, gie
> >     endif
> >   if fam_17
> >          bsf     cpusta, glintd
> >     endif
> >          endm
>
>
> BETTER?:
>  intr_off macro
>    if fam_16
>  foo:
>           bcf     intcon, gie
>           btfsc   intcon, gie
>           goto    foo
>      endif
>    if fam_17
>  bar:
>           bsf     cpusta, glintd
>           btfss   cpusta, glintd
>           goto    bar
>      endif
>           endm

>Date:    Fri, 22 Sep 2000 15:02:00 +0100
>From:    "Alan B. Pearce" <RemoveMEA.B.PearceTakeThisOuTRL.AC.UK>
>Subject: Re: [PIC]: custom mpasm mnemonics
>
>>I was the one who posted the original macro.  Is this true!?  Can an
>>interrupt really happen immediately after the instruction that disables
>>interrupts?  This seems hard to believe.  I've never seen any mention =
>of
>
>Apparently yes. I have not experienced it, but have seen code with this =
>sort of construct in it. The scenario seems to be that the interrupt =
>

> -----Original Message-----
> From: Olin Lathrop [SMTP:RemoveMEolin_piclistTakeThisOuTCOGNIVIS.COM]
> Sent: Friday, September 22, 2000 2:07 PM
> To:   PICLISTEraseME.....MITVMA.MIT.EDU
> Subject:      Re: [PIC]: custom mpasm mnemonics
>
> > WAS:
> > > intr_off macro
> > >   if fam_16
> > >          bcf     intcon, gie
> > >     endif
> > >   if fam_17
> > >          bsf     cpusta, glintd
> > >     endif
> > >          endm
> >
> >
> > BETTER?:
> >  intr_off macro
> >    if fam_16
> >  foo:
> >           bcf     intcon, gie
> >           btfsc   intcon, gie
> >           goto    foo
> >      endif
> >    if fam_17
> >  bar:
> >           bsf     cpusta, glintd
> >           btfss   cpusta, glintd
> >           goto    bar
> >      endif
> >           endm
>
> I was the one who posted the original macro.  Is this true!?  Can an
> interrupt really happen immediately after the instruction that disables
> interrupts?  This seems hard to believe.  I've never seen any mention of
> this issue in the Microchip docs, and yes, I DO read the manual.  If this
> were really true I would expect at least a one of those gray boxes
> mentioning this issue.
>
> I just re-read the interrupt section of the 16F87x and 17C7xx data sheets
> and didn't see any mention of this issue.  Both mentioned a possible
> interrupt latency of up to 2 or 3 cycles from external conditions, but I
> am
> assuming the interrupt still can't take place if they are globally
> disabled.
> Someone from Microchip please confirm/deny this?
>
> By the way, if you are going to put labels in a macro like this, you
> really
> should declare them LOCAL.
>