PIC Microcontoller Delay Method

Delay X cycles (16-65551) inclusive by Mike McLaren, K8LH

Here's a 16-bit DelayTcy routine for 16F' and 12F' devices with a 14-bit instruction core. The basic routine has 4 cycle loop timing and uses 12 words of program memory and 1 byte of data (RAM) memory. The DelayTcy macro does much of the work by preprocessing the passed "delay" constant parameter value during assembly.

;******************************************************************
;                                                                 *
;  DelayTcy(), 16..65551 Tcy         Mike McLaren, K8LH, June'07  *
;                                                                 *
;  requires the use of constant operands known at assembly time!  *
;                                                                 *
;  12 words, 1 RAM variable, 14-bit core                          *
;                            ^^^^^^^^^^^                          *
;  calling macro produces 4 instructions;                         *
;                                                                 *
DelayTcy macro  delay           ; parameter range 16..65535
        movlw   ~(high(delay-16))
        movwf   TMRH
        movlw   low(delay-16)
        call    DelayLo-(delay%4)
        endm
;                                                                 *
;  example code for simulation testing;                           *
;                                                                 *
SimTest DelayTcy(65551)         ; delay 'n' Tcy
        nop                     ; put simulator break point here
;                                                                 *
;       DelayTcy(Pulse)         ; Pulse is a constant             *
;       DelayTcy(Period-Pulse)  ; Period is also a constant       *
;                                                                 *
;******************************************************************
        nop                     ; entry point for delay%4 == 3
        nop                     ; entry point for delay%4 == 2
        nop                     ; entry point for delay%4 == 1
DelayLo addlw   -4              ; subtract 4 cycle loop time
        skpnc                   ; borrow?  yes, skip, else
        goto    DelayLo         ; do another loop
        nop                     ;
DelayHi addlw   -4              ; subtract 4 cycle loop time
        incfsz  TMRH,F          ; done?  yes, skip, else
        goto    DelayLo         ; do another loop
        goto    $+1             ;
        return                  ;
;******************************************************************

PICList 2008 contributors: o List host: MIT, Site host massmind.org, Top posters @20080828 Apptech, Jinx, Xiaofan Chen, olin piclist, Alan B. Pearce, Vitaliy, William \Chops\ Westfield, Tamas Rudnai, Cedric Chang, David VanHorn, * Page Editors: James Newton, David Cary, and YOU! * Roman Black of Black Robotics donates from sales of Linistep stepper controller kits. * Ashley Roll of Digital Nemesis donates from sales of RCL-1 RS232 to TTL converters. * Monthly Subscribers: Shultz Electronics, Timothy Weber, on-going support is MOST appreciated! * Contributors: Richard Seriani, Sr.

  .